#!/usr/bin/env expect
############################################################################
# Purpose: Test of Slurm functionality
#          Test --deadline to be used as the timelimit.
#
#          At the moment this test only really works if the DefaultTime is
#          longer than 1 hour to verify the timelimit is set accordingly.
#
# Output:  "TEST: #.#" followed by "SUCCESS" if test was successful, OR
#          "FAILURE: ..." otherwise with an explanation of the failure, OR
#          anything else indicates a failure mode that must be investigated.
############################################################################
# Copyright (C) 2015 CEA/DAM/DIF
# Written by Aline Roy <aline.roy@cea.fr>
#
# This file is part of Slurm, a resource management program.
# For details, see <https://slurm.schedmd.com/>.
# Please also read the included file: DISCLAIMER.
#
# Slurm is free software; you can redistribute it and/or modify it under
# the terms of the GNU General Public License as published by the Free
# Software Foundation; either version 2 of the License, or (at your option)
# any later version.
#
# Slurm is distributed in the hope that it will be useful, but WITHOUT ANY
# WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
# FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
# details.
#
# You should have received a copy of the GNU General Public License along
# with Slurm; if not, write to the Free Software Foundation, Inc.,
# 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA.
############################################################################
source ./globals

set test_id     "17.54"
set file_in     "test$test_id.input"
set exit_code   0
set job_id      0

print_header $test_id

#
# We must be SlurmUser or root in order to change the partition MaxTime limit,
# otherwise this test may fail.
#
if {[test_super_user] == 0} {
	log_warn "You must be SlurmUser or root to run this test."
	exit 0
}

set default_part [default_partition]
if { $default_part == "" } {
	log_error "Unable to get the default partition."
	exit 1
}

#
# Ensure that MaxTime is UNLIMITED so this test won't fail due to trying to set
# time limits greater than MaxTime. Ensure DefaultTime is UNLIMITED so the job
# time limit is what we expect.
#
spawn $scontrol update partitionname=$default_part MaxTime=-1 DefaultTime=-1
expect {
	timeout {
		log_error "scontrol not responding"
		set exit_code 1
	}
	eof {
		wait
	}
}
if { $exit_code == 1 } {
	exit $exit_code
}
set timelimit [get_partition_maximum_time_limit $default_part]
if { $timelimit != -1 } {
	log_error "Unable to update partition MaxTime to UNLIMITED"
	exit 1
}
set timelimit [get_partition_default_time_limit $default_part]
if { $timelimit != -1 } {
	log_error "Unable to update partition DefaultTime to UNLIMITED"
	exit 1
}

#
# Build input script file
#
exec $bin_rm -f $file_in
make_bash_script $file_in "$bin_sleep 1"

#
# Spawn a batch job that deadline is too late
#
set timeout $max_job_delay
spawn $sbatch --output=/dev/null --error=/dev/null --deadline now+1hour $file_in
expect {
	-re "Requested time limit is invalid" {
		set exit_code 1
		exp_continue
	}
	-re "Submitted batch job ($number)" {
		set job_id $expect_out(1,string)
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: sbatch not responding\n"
		set exit_code 1
		exp_continue
	}
	eof {
		wait
	}
}
if {$job_id == 0} {
	send_user "\nFAILURE: job submission failed\n"
	exit 1
}

if {[wait_for_job $job_id DONE] != 0} {
	send_user "\nFAILURE: job failed to run to completion\n"
	exit 1
}

#
# verify time limit
#
spawn $scontrol show job $job_id
expect {
	-re "TimeLimit=00:59:" {
		exp_continue
	}
	-re "TimeLimit=01:00:00" {
		exp_continue
	}
	-re "TimeLimit=" {
		send_user "\nFAILURE: time limit is different from deadline\n"
		set exit_code 1
		exp_continue
	}
	timeout {
		send_user "\nFAILURE: scontrol not responding\n"
		set exit_code 1
		exp_continue
	}
	eof {
		wait
	}
}

#
# Restore partition MaxTime and DefaultTime.
# reconfigure will set exit_code and log any errors if it fails.
#
reconfigure

if {$exit_code == 0} {
	exec $bin_rm -f $file_in
	send_user "\nSUCCESS\n"
}
exit $exit_code